10 REM ****************************
11 REM F.A. Cup  2020-21 QL Edition
12 REM ****************************
13 REM      Spectrum  original
14 REM       by  G.L. Maynard
15 REM ZX Computing  April/May 1983
16 REM ****************************
17 REM        QL  conversion
18 REM       by J.R. Waterman
19 REM     21 - 26 October 2020
20 REM ****************************

30 init=1
40 setup_screen
50 IF init=1 THEN title
60 setup_arrays
70 wait_at_start
80 exclude_top_divs
100 REM *** MAIN LOOP STARTS HERE!
110 FOR round=1 TO 8
120   draw_round
130   SEL ON round
140     =1,3: print_draw_2
150     =REMAINDER: print_draw_1
160   END SEL
170   print_results
180 NEXT round
200 winners
210 INK 0: CSIZE 0,0: CURSOR 27,180
220 PRINT "Type RUN for another cup - change line 30 to ";CHR$(34);"init=0";CHR$(34);" to skip the intro."

999 STOP

1000 REMark ***********************
1001 DEF PROC setup_screen
1002 REMark ***********************
1005 MODE 4
1010 OPEN #4,scr_512x226a0x0
1015 PAPER #4,176: CLS #4
1020 WINDOW #0,512,30,0,226
1025 PAPER #0,0: INK #0,7: CLS #0
1030 WINDOW #2,488,200,12,20
1040 WINDOW #1,488,200,12,20
1045 PAPER #1,7: INK #1,0: CSIZE #1,1,0: CLS #1
1050 OPEN #3,scr_488x10a12x6
1055 PAPER #3,7: INK #3,0: CSIZE #3,1,0: CLS #3
1070 END DEF setup_screen

1100 REMark ***********************
1101 DEF PROC title
1102 REMark ***********************
1110 CSIZE 3,1: AT 1,11: INK 0
1120 PRINT "F.A. CUP"
1130 CSIZE 2,1: INK 4: CURSOR 42,80
1140 PRINT "Spectrum original by G.L. Maynard"
1145 CURSOR 78,100
1150 PRINT "ZX Computing April/May 1983"
1155 INK 2: AT 7,5
1160 PRINT "QL conversion by J.R. Waterman"\ TO 10;"21 - 26 October 2020"
1170 back_home
1180 INK 0: CSIZE 1,0: CLS
1190 END DEF title

1200 REMark ***********************
1201 DEF PROC setup_arrays
1202 REMark ***********************
1210 LOC a,q$,c1%,c2%,c3%,c4%,c5%,c6%
1220 DIM a$(124,30)
1230 DIM c%(124): DIM d%(124): DIM e%(124)
1240 AT #3,0,1: PRINT #3,"THE F. A. CUP "
1250 CSIZE 3,1: AT 1,4: CURSOR 72,20
1255 PRINT "WHICH SEASON'S TEAMS?"
1260 INK 4: AT 4,6: PRINT "1 = 1982/83 SEASON"
1265 CSIZE 1,0: PRINT TO 2;"(the active season when the original program was written)"
1270 CSIZE 3,1: INK 2: AT 7,6: PRINT "2 = 2020/21 SEASON"
1275 CSIZE 1,0: PRINT TO 5;"(the active season when this program was converted)"
1280 INK 0
1290 REP loop
1300   q$=INKEY$(-1)
1310   IF q$="1" or q$="2" THEN EXIT loop
1320 END REP loop
1330 season=q$
1340 AT #3,0,15
1350 SEL ON season
1360   =1
1370     c1%=11: c2%=11: c3%=22: c4%=24: c5%=24: c6%=32
1380     INK #0,4: PAPER #3,4: CLS #3
1390     PRINT #3," THE F. A. CUP 1982-83"
1400     RESTORE 9000
1410   =2
1420     c1%=10: c2%=10: c3%=24: c4%=24: c5%=24: c6%=32
1430     INK #0,2: PAPER #3,2: INK #3,7: CLS #3
1440     PRINT #3," THE F. A. CUP 2020-21"
1450     RESTORE 8000
1460 END SEL
1470 FOR a=1 TO 124: READ a$(a): NEXT a
1480 FOR a=1 TO c1%: c%(a)=1: NEXT a
1490 FOR a=c1%+1 TO c1%+c2%: c%(a)=2: NEXT a
1500 FOR a=c1%+c2%+1 TO c1%+c2%+c3%: c%(a)=3: NEXT a
1510 FOR a=c1%+c2%+c3%+1 TO c1%+c2%+c3%+c4%: c%(a)=4: NEXT a
1520 FOR a=c1%+c2%+c3%+c4%+1 TO c1%+c2%+c3%+c4%+c5%: c%(a)=5: NEXT a
1530 FOR a=c1%+c2%+c3%+c4%+c5%+1 TO c1%+c2%+c3%+c4%+c5%+c6%: c%(a)=6: NEXT a
1540 END DEF setup_arrays

1600 REMark ***********************
1601 DEF PROC wait_at_start
1602 REMark ***********************
1610 LOC q$
1620 AT #0,1,20: PRINT #0,"Press SPACE to kick off the magic of the cup!"
1630 REP loop
1640   q$=INKEY$(-1)
1650   IF q$=" " THEN EXIT loop
1660 END REP loop
1670 CLS #0: CLS
1680 RANDOMISE
1690 END DEF wait_at_start

1800 REMark ***********************
1801 DEF PROC exclude_top_divs
1802 REMark ***********************
1810 LOC a
1820 FOR a=1 TO 124
1830   d%(a)=0
1840   IF c%(a)>3 THEN d%(a)=1
1850 NEXT a
1860 END DEF exclude_top_divs

2000 REMark ***********************
2001 DEF PROC draw_round
2002 REMark ***********************
2010 LOC a
2020 round_beeps
2030 SEL ON round
2040   =8
2050     AT #3,0,39: PRINT #3,"           FINAL DRAW"
2060     AT #0,1,20: PRINT #0,"The draw for the final is about to be made..."
2070   =7
2080     AT #3,0,39: PRINT #3,"      SEMI-FINAL DRAW"
2090     AT #0,1,18: PRINT #0,"The draw for the semi-final is about to be made..."
2100   =6
2110     AT #3,0,39: PRINT #3,"   QUARTER-FINAL DRAW"
2120     AT #0,1,16: PRINT #0,"The draw for the quarter-final is about to be made..."
2130   =REMAINDER
2140     AT #3,0,39: PRINT #3,"         ROUND ";round;" DRAW"
2150     AT #0,1,21: PRINT #0,"The draw for round ";round;" is about to be made..."
2160 END SEL
2170 IF round<3 THEN teams=80/round
2180 IF round>2 THEN teams=64/(2^(round-3))
2190 IF round=3 THEN
2200   FOR a=1 TO 44
2210   d%(a)=1
2220   NEXT a
2230 END IF
2240 FOR a=1 TO teams
2250   REP loop
2260     e%(a)=RND(1 TO 124)
2270     IF d%(e%(a))=1 THEN EXIT loop
2280   END REP loop
2290   d%(e%(a))=0
2300 NEXT a
2310 CLS #0
2320 END DEF draw_round

2400 REMark ***********************
2401 DEF PROC print_draw_1
2402 REMark ***********************
2410 LOC a
2420 CLS #0: AT #0,1,33: PRINT #0,"Printing matches..."
2430 CLS: AT 0,0
2440 FOR a=1 TO teams-1 STEP 2
2445   AT ((a+1)/2)-1,0: PRINT FILL$(" ",61)
2450   AT ((a+1)/2)-1,1: PRINT a$(e%(a)); TO 30;"v"; TO 34;a$(e%(a+1))
2460   draw_beep
2470 NEXT a
2475 CLS #0
2480 next_draw_page 2
2490 END DEF print_draw_1

2500 REMark ***********************
2501 DEF PROC print_draw_2
2502 REMark ***********************
2510 LOC a,b,c
2520 CLS #0: AT #0,1,31: PRINT #0,"Printing matches 1-20..."
2530 CLS: AT 0,0
2540 FOR a=1 TO 39 STEP 2
2545   AT ((a+1)/2)-1,0: PRINT FILL$(" ",61)
2550   AT ((a+1)/2)-1,1: PRINT a$(e%(a)); TO 30;"v"; TO 34;a$(e%(a+1))
2560   draw_beep
2570 NEXT a
2580 next_draw_page 1
2590 CLS #0: AT #0,1,30: PRINT #0,"Printing matches 21-";(teams/2);"..."
2600 AT 0,0
2610 FOR b=41 TO teams-1 STEP 2
2615   AT ((b+1)/2)-21,0: PRINT FILL$(" ",61)
2620   AT ((b+1)/2)-21,1: PRINT a$(e%(b)); TO 30;"v"; TO 34;a$(e%(b+1))
2630   draw_beep
2640 NEXT b
2650 IF round=3 THEN
2660   FOR c=12 TO 19: AT c,0: PRINT FILL$(" ",61): NEXT c
2665 END IF
2670 CLS #0
2680 next_draw_page 2
2690 END DEF print_draw_2

2700 REMark ***********************
2701 DEF PROC next_draw_page (q)
2702 REMark ***********************
2710 LOC q$
2720 CLS #0
2730 SEL on q
2740   =1
2750     AT #0,1,30: PRINT #0,"Press SPACE for next page"
2760   =2
2770     AT #0,1,29: PRINT #0,"Press SPACE for the results"
2780 END SEL
2790 REP loop
2800   q$=INKEY$(-1)
2810   IF q$=" " THEN EXIT loop
2820 END REP loop
2830 CLS #0
2840 END DEF next_draw_page

2900 REMark ***********************
2901 DEF PROC wait_next_result
2902 REMark ***********************
2910 LOC q$
2920 AT #0,1,29: PRINT #0,"Press SPACE for next result"
2930 REP loop
2940   q$=INKEY$(-1)
2950   IF q$=" " THEN EXIT loop
2960 END REP loop
2980 CLS #0
2990 END DEF wait_next_result

3000 REMark ***********************
3001 DEF PROC print_results
3002 REMark ***********************
3010 LOC a
3020 CLS
3030 SEL ON round
3040   =8
3050     AT #3,0,39: PRINT #3,"    FINAL: AT WEMBLEY"
3060   =7
3070     AT #3,0,39: PRINT #3,"   SEMI-FINAL RESULTS"
3080   =6
3090     AT #3,0,39: PRINT #3,"QUARTER-FINAL RESULTS"
3100   =REMAINDER
3110     AT #3,0,39: PRINT #3,"      ROUND ";round;" RESULTS"
3120 END SEL
3130 round_beeps
3140 AT 0,0
3150 FOR a=1 TO teams-1 STEP 2
3160   wait_next_result 
3170   make_result
3180   PRINT TO 1;a$(e%(a)); TO 28;homesc;" - ";awaysc; TO 34;a$(e%(a+1))
3190   IF homesc>awaysc THEN d%(e%(a))=1
3200   IF awaysc>homesc THEN d%(e%(a+1))=1
3210   IF homesc=awaysc THEN d%(e%(a))=2
3220   next_result_beeps
3230 NEXT a
3240 pause_before_replays
3260 check_for_replays
3270 pause_before_next_round
3280 END DEF print_results

3300 REMark ***********************
3301 DEF PROC check_for_replays
3302 REMark ***********************
3310 LOC a
3320 draws=0
3330 FOR a=1 TO teams-1 STEP 2
3340   IF d%(e%(a))=2 THEN draws=draws+1
3350 NEXT a
3360 IF draws=0 THEN RET
3370 replays
3390 END DEF check_for_replays

3400 REMark ***********************
3401 DEF PROC replays
3402 REMark ***********************
3410 LOC a
3420 CLS
3430 SEL ON round
3440   =8
3450     AT #3,0,39: PRINT #3,"    FINAL: AT WEMBLEY"
3460   =7
3470     AT #3,0,39: PRINT #3,"   SEMI-FINAL REPLAYS"
3480   =6
3490     AT #3,0,39: PRINT #3,"QUARTER-FINAL REPLAYS"
3500   =REMAINDER
3510     AT #3,0,39: PRINT #3,"      ROUND ";round;" REPLAYS"
3520 END SEL
3530 round_beeps
3540 AT 0,0
3550 FOR a=1 TO teams-1 STEP 2
3560   IF d%(e%(a))=2 THEN
3570    wait_next_result 
3580     make_result
3590     PRINT TO 1;a$(e%(a+1)); TO 28;awaysc;" - ";homesc; TO 34;a$(e%(a))
3600     d%(e%(a))=0: d%(e%(a+1))=0
3610     IF homesc>awaysc THEN d%(e%(a))=1
3620     IF awaysc>homesc THEN d%(e%(a+1))=1
3630     IF awaysc=homesc THEN d%(e%(a))=2
3640     next_result_beeps
3650   END IF
3660 NEXT a
3670 IF draws<>0 THEN PAUSE 100: REM yeet this line?
3680 check_for_replays
3690 PAUSE 150
3700 END DEF replays

3800 REMark ***********************
3801 DEF PROC pause_before_replays
3802 REMark ***********************
3810 LOC q$
3820 CLS #0: AT #0,1,29: PRINT #0,"Press SPACE for the replays"
3830 REP loop
3840   q$=INKEY$(-1)
3850   IF q$=" " THEN EXIT loop
3860 END REP loop
3870 CLS #0
3880 END DEF pause_before_replays

3900 REMark ***********************
3901 DEF PROC pause_before_next_round
3902 REMark ***********************
3910 LOC q$
3920 CLS #0: AT #0,1,27: PRINT #0,"Press SPACE for the next round"
3930 REP loop
3940   q$=INKEY$(-1)
3950   IF q$=" " THEN EXIT loop
3960 END REP loop
3970 CLS #0: CLS
3980 END DEF pause_before_next_round

4000 REMark ***********************
4001 DEF PROC make_result
4002 REMark ***********************
4010 LOC u,actdif,diff,home,away
4020 actdif=c%(e%(a))-c%(e%(a+1))
4030 DATA -5,9.1,1.6,-4,7.2,2.05,-3,6.2,2.45,-2,4.7,3.1,-1,4.35,3.65,0,4.35,4.1,1,4,4.2,2,3.5,4.4,3,3.2,5.05,4,3.05,5.2,5,2.05,7.15
4040 RESTORE 4030
4050 u=1
4060 REP loop
4070   READ diff,home,away
4080   IF diff=actdif THEN
4090     homesc=RND(home-1)
4100     awaysc=RND(away-1)
4110     EXIT loop
4120   END IF
4130 u=u+1
4140 END REP loop
4150 IF d%(e%(a))=2 THEN RETurn
4160 END DEF make_result

4500 REMark ***********************
4501 DEF PROC winners
4502 REMark ***********************
4510 LOC a,w$,w%,s$
4520 a=1
4530 REP loop
4540   IF d%(a)=1 THEN
4550     w$=a$(a)
4560     w%=8*(30-LEN(w$))
4570     EXIT loop
4580   END IF
4590 a=a+1
4600 END REP loop
4610 SEL ON season
4620   =1
4630     s$="1982-83"
4640   =2
4650     s$="2021-22"
4660 END SEL
4670 CSIZE 3,1: INK 4: AT 3,6
4680 PRINT "The winners of the"
4690 PRINT TO 5;s$;" F.A. Cup are"
4700 INK 2: CURSOR w%,120
4710 PRINT w$
4720 back_home
4730 END DEF winners

7000 REMark ***********************
7001 DEF PROC draw_beep
7002 REMark ***********************
7010 BEEP 2115,27
7020 END DEF draw_beep

7100 REMark ***********************
7101 DEF PROC round_beeps
7102 REMark ***********************
7110 LOC n,m,note
7120 RESTORE 7180
7130 FOR n=1 TO 8
7140   READ note
7150   BEEP 5000,note
7155   FOR m=1 TO 30: NEXT m
7160 NEXT n
7165 FOR m=1 TO 7: NEXT m
7170 BEEP
7180 DATA 96,44,75,33,61,27,44,18
7190 END DEF round_beeps

7200 REMark ***********************
7201 DEF PROC next_result_beeps
7202 REMark ***********************
7210 LOC n
7220 BEEP 5000,96
7230 FOR n=1 TO 20: NEXT n
7240 BEEP 5000,18
7250 FOR n=1 TO 27: NEXT n
7260 BEEP
7270 END DEF next_result_beeps

7500 REMark ***********************
7501 DEF PROC back_home
7502 REMark ***********************
7510 LOC a,p,l,notes,note,dur
7515 p=9: l=32767: notes=61
7520 RESTORE 7700
7530 FOR a=1 to notes
7540   READ note,dur
7550   BEEP l,note
7560   PAUSE p*dur
7570 NEXT a
7580 BEEP: PAUSE p
7590 BEEP l,31: PAUSE p: BEEP: PAUSE p
7600 FOR a=1 TO 3
7610   BEEP l,31: PAUSE p
7620 NEXT a: BEEP: PAUSE p
7630 FOR a=1 TO 4
7640   BEEP l,31: PAUSE p
7650 NEXT a: BEEP: PAUSE p
7660 FOR a=1 TO 2
7670   BEEP l,31: PAUSE p
7680 NEXT a: BEEP
7700 DATA 44,2,31,6,54,1,50,1,44,1,38,1,33,1,31,2,33,2,31,1,27,2,23,2,27,2,31,2,38,6,36,2,33,6
7710 DATA 61,1,54,1,50,1,44,1,38,1,33,2,31,2,33,1,38,2,44,2,31,2,27,2,23,4,27,4,31,6
7720 DATA 54,1,50,1,44,1,38,1,33,1,31,2,33,2,31,1,27,6,47,1,44,1,38,1,33,1,31,1,27,2,31,2,27,1
7730 DATA 23,2,23,2,23,2,23,2,23,1,27,2,29,2,27,1,23,2,21,4,27,4,31,1
7740 END DEF back_home


8000 REMark ***********************
8001 REMark **   2020-21 TEAMS   **
8002 REMark ***********************
8003 REMark Class 1 = Premier top
8004 REMark 10 teams
8100 REMark ***********************
8101 DATA "ARSENAL"
8102 DATA "BURNLEY"
8103 DATA "CHELSEA"
8104 DATA "LEICESTER CITY"
8105 DATA "LIVERPOOL"
8106 DATA "MANCHESTER CITY"
8107 DATA "MANCHESTER UNITED"
8108 DATA "SHEFFIELD UNITED"
8109 DATA "TOTTENHAM HOTSPUR"
8110 DATA "WOLVERHAMPTON WANDERERS"
8197 REMark ***********************
8198 REMark Class 2 = Prem. bottom
8199 REMark 10 teams
8200 REMark ***********************
8201 DATA "ASTON VILLA"
8202 DATA "BRIGHTON & HOVE ALBION"
8203 DATA "CRYSTAL PALACE"
8204 DATA "EVERTON"
8205 DATA "FULHAM"
8206 DATA "LEEDS UNITED"
8207 DATA "NEWCASTLE UNITED"
8208 DATA "SOUTHAMPTON"
8209 DATA "WEST BROMWICH ALBION"
8210 DATA "WEST HAM UNITED"
8297 REMark ***********************
8298 REMark Class 3 = Championship
8299 REMark 24 teams
8300 REMark ***********************
8301 DATA "BARNSLEY"
8302 DATA "BIRMINGHAM CITY"
8303 DATA "BLACKBURN ROVERS"
8304 DATA "BOURNEMOUTH"
8305 DATA "BRENTFORD"
8306 DATA "BRISTOL CITY"
8307 DATA "CARDIFF CITY"
8308 DATA "COVENTRY CITY"
8309 DATA "DERBY COUNTY"
8310 DATA "HUDDERSFIELD TOWN"
8311 DATA "LUTON TOWN"
8312 DATA "MIDDLESBROUGH"
8313 DATA "MILLWALL"
8314 DATA "NORWICH CITY"
8315 DATA "NOTTINGHAM FOREST"
8316 DATA "PRESTON NORTH END"
8317 DATA "QUEENS PARK RANGERS"
8318 DATA "READING"
8319 DATA "ROTHERHAM UNITED"
8320 DATA "SHEFFIELD WEDNESDAY"
8321 DATA "STOKE CITY"
8322 DATA "SWANSEA CITY"
8323 DATA "WATFORD"
8324 DATA "WYCOMBE WANDERERS"
8397 REMark ***********************
8398 REMark Class 4 = League One
8399 REMark 24 teams
8400 REMark ***********************
8401 DATA "ACCRINGTON STANLEY"
8402 DATA "A.F.C. WIMBLEDON"
8403 DATA "BLACKPOOL"
8404 DATA "BRISTOL ROVERS"
8405 DATA "BURTON ALBION"
8406 DATA "CHARLTON ATHLETIC"
8407 DATA "CREWE ALEXANDRA"
8408 DATA "DONCASTER ROVERS"
8409 DATA "FLEETWOOD TOWN"
8410 DATA "GILLINGHAM"
8411 DATA "HULL CITY"
8412 DATA "IPSWICH TOWN"
8413 DATA "LINCOLN CITY"
8414 DATA "MILTON KEYNES DONS"
8415 DATA "NORTHAMPTON TOWN"
8416 DATA "OXFORD UNITED"
8417 DATA "PETERBOROUGH UNITED"
8418 DATA "PLYMOUTH ARGYLE"
8419 DATA "PORTSMOUTH"
8420 DATA "ROCHDALE"
8421 DATA "SHREWSBURY TOWN"
8422 DATA "SUNDERLAND"
8423 DATA "SWINDON TOWN"
8424 DATA "WIGAN ATHLETIC"
8497 REMark ***********************
8498 REMark Class 5 = League Two
8499 REMark 24 teams
8500 REMark ***********************
8501 DATA "BARROW"
8502 DATA "BOLTON WANDERERS"
8503 DATA "BRADFORD CITY"
8504 DATA "CAMBRIDGE UNITED"
8505 DATA "CARLISLE UNITED"
8506 DATA "CHELTENHAM TOWN"
8507 DATA "COLCHESTER UNITED"
8508 DATA "CRAWLEY TOWN"
8509 DATA "EXETER CITY"
8510 DATA "FOREST GREEN ROVERS"
8511 DATA "GRIMSBY TOWN"
8512 DATA "HARROGATE TOWN"
8513 DATA "LEYTON ORIENT"
8514 DATA "MANSFIELD TOWN"
8515 DATA "MORECAMBE"
8516 DATA "NEWPORT COUNTY"
8517 DATA "OLDHAM ATHLETIC"
8518 DATA "PORT VALE"
8519 DATA "SALFORD CITY"
8520 DATA "SCUNTHORPE UNITED"
8521 DATA "SOUTHEND UNITED"
8522 DATA "STEVENAGE"
8523 DATA "TRANMERE ROVERS"
8524 DATA "WALSALL"
8597 REMark ***********************
8598 REMark Class 6 = Non-league
8599 REMark 32 teams
8600 REMark ***********************
8601 DATA "A.F.C. FYLDE"
8602 DATA "BANBURY UNITED"
8603 DATA "BARNET"
8604 DATA "BISHOP'S STORTFORD"
8605 DATA "BOREHAM WOOD"
8606 DATA "BRACKLEY TOWN"
8607 DATA "BROMLEY"
8608 DATA "CANVEY ISLAND"
8609 DATA "CHESTERFIELD"
8610 DATA "CHORLEY"
8611 DATA "CONCORD RANGERS"
8612 DATA "CRAY VALLEY PAPER MILLS"
8613 DATA "DAGENHAM & REDBRIDGE"
8614 DATA "DARLINGTON"
8615 DATA "EASTBOURNE BOROUGH"
8616 DATA "EASTLEIGH"
8617 DATA "F.C. UNITED OF MANCHESTER"
8618 DATA "HAMPTON & RICHMOND BOROUGH"
8619 DATA "HARTLEPOOL UNITED"
8620 DATA "HAVANT & WATERLOOVILLE"
8621 DATA "HAYES & YEADING UNITED"
8622 DATA "KING'S LYNN TOWN"
8623 DATA "MALDON & TIPTREE"
8624 DATA "MARINE"
8625 DATA "OXFORD CITY"
8626 DATA "SKELMERSDALE UNITED"
8627 DATA "SOLIHULL MOORS"
8628 DATA "SOUTH SHIELDS"
8629 DATA "TONBRIDGE ANGELS"
8630 DATA "TORQUAY UNITED"
8631 DATA "WOKING"
8632 DATA "YEOVIL TOWN"

9000 REMark ***********************
9001 REMark **   1982-83 TEAMS   **
9002 REMark ***********************
9003 REMark Class 1 = Div. 1 top
9004 REMark 11 teams
9100 REMark ***********************
9101 DATA "ARSENAL"
9102 DATA "ASTON VILLA"
9103 DATA "EVERTON"
9104 DATA "IPSWICH TOWN"
9105 DATA "LIVERPOOL"
9106 DATA "MANCHESTER CITY"
9107 DATA "MANCHESTER UNITED"
9108 DATA "SOUTHAMPTON"
9109 DATA "SWANSEA CITY"
9110 DATA "TOTTENHAM HOTSPUR"
9111 DATA "WEST HAM UNITED"
9197 REMark ***********************
9198 REMark Class 2 = Div. 1 bottom
9199 REMark 11 teams
9200 REMark ***********************
9201 DATA "BIRMINGHAM CITY"
9202 DATA "BRIGHTON & HOVE ALBION"
9203 DATA "COVENTRY CITY"
9204 DATA "LUTON TOWN"
9205 DATA "NORWICH CITY"
9206 DATA "NOTTINGHAM FOREST"
9207 DATA "NOTTS COUNTY"
9208 DATA "STOKE CITY"
9209 DATA "SUNDERLAND"
9210 DATA "WATFORD"
9211 DATA "WEST BROMWICH ALBION"
9297 REMark ***********************
9298 REMark Class 3 = Div. 2
9299 REMark 22 teams
9300 REMark ***********************
9301 DATA "BARNSLEY"
9302 DATA "BLACKBURN ROVERS"
9303 DATA "BOLTON WANDERERS"
9304 DATA "BURNLEY"
9305 DATA "CAMBRIDGE UNITED"
9306 DATA "CARLISLE UNITED"
9307 DATA "CHARLTON ATHLETIC"
9308 DATA "CHELSEA"
9309 DATA "CRYSTAL PALACE"
9310 DATA "DERBY COUNTY"
9311 DATA "FULHAM"
9312 DATA "GRIMSBY TOWN"
9313 DATA "LEEDS UNITED"
9314 DATA "LEICESTER CITY"
9315 DATA "MIDDLESBROUGH"
9316 DATA "NEWCASTLE UNITED"
9317 DATA "OLDHAM ATHLETIC"
9318 DATA "QUEENS PARK RANGERS"
9319 DATA "ROTHERHAM UNITED"
9320 DATA "SHEFFIELD WEDNESDAY"
9321 DATA "SHREWSBURY TOWN"
9322 DATA "WOLVERHAMPTON WANDERERS"
9397 REMark ***********************
9398 REMark Class 4 = Div. 3
9399 REMark 24 teams
9400 REMark ***********************
9401 DATA "BOURNEMOUTH"
9402 DATA "BRADFORD CITY"
9403 DATA "BRENTFORD"
9404 DATA "BRISTOL ROVERS"
9405 DATA "CARDIFF CITY"
9406 DATA "CHESTERFIELD"
9407 DATA "DONCASTER ROVERS"
9408 DATA "EXETER CITY"
9409 DATA "GILLINGHAM"
9410 DATA "HUDDERSFIELD TOWN"
9411 DATA "LINCOLN CITY"
9412 DATA "MILLWALL"
9413 DATA "NEWPORT COUNTY"
9414 DATA "ORIENT"
9415 DATA "OXFORD UNITED"
9416 DATA "PLYMOUTH ARGYLE"
9417 DATA "PORTSMOUTH"
9418 DATA "PRESTON NORTH END"
9419 DATA "READING"
9420 DATA "SHEFFIELD UNITED"
9421 DATA "SOUTHEND UNITED"
9422 DATA "WALSALL"
9423 DATA "WIGAN ATHLETIC"
9424 DATA "WREXHAM"
9497 REMark ***********************
9498 REMark Class 5 = Div. 4
9499 REMark 24 teams
9500 REMark ***********************
9501 DATA "ALDERSHOT"
9502 DATA "BLACKPOOL"
9503 DATA "BRISTOL CITY"
9504 DATA "BURY"
9505 DATA "CHESTER CITY"
9506 DATA "COLCHESTER UNITED"
9507 DATA "CREWE ALEXANDRA"
9508 DATA "DARLINGTON"
9509 DATA "HALIFAX TOWN"
9510 DATA "HARTLEPOOL UNITED"
9511 DATA "HEREFORD UNITED"
9512 DATA "HULL CITY"
9513 DATA "MANSFIELD TOWN"
9514 DATA "NORTHAMPTON TOWN"
9515 DATA "PETERBOROUGH UNITED"
9516 DATA "PORT VALE"
9517 DATA "ROCHDALE"
9518 DATA "SCUNTHORPE UNITED"
9519 DATA "STOCKPORT COUNTY"
9520 DATA "SWINDON TOWN"
9521 DATA "TORQUAY UNITED"
9522 DATA "TRANMERE ROVERS"
9523 DATA "WIMBLEDON"
9524 DATA "YORK CITY"
9597 REMark ***********************
9598 REMark Class 6 = Non-league
9599 REMark 32 teams
9600 REMark ***********************
9601 DATA "ALTRINCHAM"
9602 DATA "BARNET"
9603 DATA "BISHOP'S STORTFORD"
9604 DATA "BOSTON UNITED"
9605 DATA "CARSHALTON ATHLETIC"
9606 DATA "CHESHAM UNITED"
9607 DATA "DAGENHAM"
9608 DATA "DARTFORD"
9609 DATA "ENFIELD"
9610 DATA "FOLKESTONE"
9611 DATA "HOLBEACH UNITED"
9612 DATA "HORWICH R.M.I."
9613 DATA "KETTERING TOWN"
9614 DATA "MACCLESFIELD TOWN"
9615 DATA "MAIDSTONE UNITED"
9616 DATA "MOSSLEY"
9617 DATA "NORTH SHIELDS"
9618 DATA "NORTHWICH VICTORIA"
9619 DATA "SCARBOROUGH"
9620 DATA "SHEPSHED CHARTERHOUSE"
9621 DATA "SLOUGH TOWN"
9622 DATA "TELFORD UNITED"
9623 DATA "WEALDSTONE"
9624 DATA "WEYMOUTH"
9625 DATA "WIMBORNE TOWN"
9626 DATA "WINDSOR & ETON"
9627 DATA "WOKINGHAM TOWN"
9628 DATA "WORCESTER CITY"
9629 DATA "WORKINGTON"
9630 DATA "WORTHING"
9631 DATA "WYCOMBE WANDERERS"
9632 DATA "YEOVIL TOWN"

9700 REMark ***********************
9701 DEF PROC test_arrays_1
9702 REMark ***********************
9710 LOC a
9720 CLS: AT 0,0
9730 PRINT "CL. TEAM"
9740 FOR a=1 TO 124
9750 PRINT c%(a); TO 4;a$(a); TO 32; LEN(a$(a))
9760 NEXT a
9770 END DEF test_arrays_1
9800 REMark ***********************
9801 DEF PROC test_arrays_2
9802 REMark ***********************
9810 LOC a,b
9820 b=7: INK 0
9830 CLS: AT 0,0
9840 FOR a=1 TO 124
9850 PAPER b: PRINT a$(a);
9860 b=b-3: IF b=1 THEN b=7
9870 NEXT a
9880 END DEF test_arrays_2